dh-Materialien
Einführung in Maple    
Übungen
 

Die Eulergerade

> restart; with(geometry):

Definition des Dreiecks mit den Eckpunkten  A, B und  C:

> point(A, [-3, 2]): point(B, -1, 8): point(C, 7, 1):
  triangle(Dreieck, [A, B, C]):

Benennung der Seiten des Dreiecks:

> line(a, [B, C]): line(b, [C, A]): line(c, [A, B]):

Bestimmen der Höhen ha, hb und  hc:

> PerpendicularLine(ha, A, a):
  PerpendicularLine(hb, B, b):
  PerpendicularLine(hc, C, c):

Bestimmen der Mittelsenkrechten  ma, mb und mc:

> PerpenBisector(ma, B, C):
  PerpenBisector(mb, A, C):
  PerpenBisector(mc, A, B):

Bestimmen der Seitenhalbierenden  sa, sb und sc:

> line(sa, [A, midpoint(Ma, B, C)]):
  line(sb, [B, midpoint(Mb, C, A)]):
  line(sc, [C, midpoint(Mc, A, B)]):

Die Eulergerade durch die Punkte H, U und S:

> EulerLine(El, Dreieck):

> draw([Dreieck (thickness = 2),
        ha, hb, hc,
        ma, mb, mc,
        sa, sb, sc,
        El (thickness = 2)],
    axes = NONE,
    color = [black,
             maroon, maroon, maroon,
             green, green, green,
             blue, blue, blue, red]);

Der Höhenschnittpunkt H, der Umkreismittelpunkt U und der Schwerpunkt S liegen immer auf einer Geraden.

Beweis:
Sei ein beliebiges Dreieck mit den Eckpunkten A, B und C gegeben.
Hierbei wird Folgendes als bekannt vorausgesetzt:
   Alle Höhen schneiden sich in H, alle Mittelsenkrechten in U und alle Seitenhalbierenden in S.
   Ferner sei bereits bekannt, in welchem Verhältnis S jede der Seitenhalbierenden teilt.
Ohne Beschränkung der Allgemeinheit sei A(0| 0), B(a| 0) und C(b| c) mit
irgendwelchen von 0 verschiedenen Zahlen a, b und c.

> restart; with(geometry):
  point(A, 0, 0): point(B, a, 0):point (C, b, c):

Berechnen des Mittelpunktes der Strecke zwischen B und C:

> midpoint(M, B, C):
  coordinates(M);

[a/2+b/2, c/2]

S teilt die Strecke zwischen A und M im Verhältnis 2 : 1, also gilt:

> x[M]:= HorizontalCoord(M):
  y[M]:= VerticalCoord(M):
  point(S, 2/3*x[M], 2/3*y[M]):
  coordinates(S);

[a/3+b/3, c/3]

U hat die x-Koordinate a/2 und muss zu jedem der Dreieckspunkte den gleichen Abstand haben:

> point(U, a/2, y[U]):
  coordinates(U);
  d[A]:= distance(A, U);
  d[C]:= distance(C, U);
  y[U]:= solve(d[A] = d[C], y[U]);

Der Umkreismittelpunkt U:

> coordinates(U);

U und S definieren eine Gerade g.
Berechnung der Steigung m dieser Geraden:

> Delta[y]:= VerticalCoord(S) - VerticalCoord(U);
  Delta[x]:= HorizontalCoord(S) - HorizontalCoord(U);
  m:= simplify(Delta[y]/Delta[x]);

Die Gleichung der Geraden g:

> g:= y = m*x + k:
  gl:= subs(x = HorizontalCoord(S), y = VerticalCoord(S), g):
  k:= solve(gl, k);
  g;

Der Höhenschnittpunkt H:

> h:= x -> (a-b)/c*x: # Höhe auf BC
  point(H, b, h(b)):
  coordinates(H);

[b, (a-b)*b/c]

Liegt H auf der Geraden g?

> gl:= subs(x = b, g):
  y:= solve(gl, y);

y = (a-b)*b/c

Dies war zu zeigen.


 Home   Back   Top