dh-Materialien
Einführung in Maple    
Übungen
 

Rechnen mit Gleichungen

Umformen einfacher Gleichungen mit isolate:

> restart;

Definition des elektrischen Widerstandes R mit Hilfe der Gleichung  glWid:

> glWid:= R = U/J;


Auflösen von glWid nach J:

> isolate(glWid, J);

glWid := R = U/J
J = U/R

Definition der Exponentialgleichung  glExp;
Hinschreiben der Gleichung  glExp:

> glExp:= 10 = 2^t:
  glExp;

10 = 2^t

Lösen der Gleichung  glExp:

> isolate(glExp, t);
  t:= fsolve(glExp, t);

t = ln(10)/ln(2)
t := 3.321928095

Lösen von Gleichungen mit solve:

> restart;
  Digits:= 4:

Polynomgleichung ausschließlich mit reellen Lösungswerten:

> solve(x^4 + x^3 - 7*x^2 - 3.5*x + 9 = 0, x);

1.048, 2.128, -1.518, -2.659

Polynomgleichung mit reellen und komplexen Lösungswerten:

> solve(x^4 - x^3 - 7*x^2 - 3.5*x + 9 = 0, x);

Lösung derselben Gleichung im Reellen:

> fsolve(x^4 - x^3 - 7*x^2 - 3.5*x + 9 = 0, x);

0.9068, 3.233

Polynomgleichung mit Formvariablen:

> solve(a*x^4 - b*x^3 = 0, x);

0,0,0,b/a

Bestimmen der numerischen Werte der von solve gefundenen Lösungen einer Gleichung:

> evalf(solve (2^n = 10 + n, n));

-9.999, 3.786

Mit dem solve-Befehl erhält man nicht immer alle Lösungen einer Gleichung:

> solve(cos(x) = 0, x);

Pi/2

Aber:

> _EnvAllSolutions:= true:
  solve(cos(x) = 0, x);

lgn:= Pi/2 + Pi*_Z1~

Die Konstante _Z1 ist ganzzahlig:

> is(_Z1, integer);

true

Umbennen von _Z1:

> lgn:= subs(_Z1 = k, lgn);

lgn:= Pi/2 + Pi*k

Lösen von Gleichungen mit fsolve:

> restart;
  Digits:= 4:

fsolve liefert in der Regel jeweils immer nur einen reellen Lösungswert:

> fsolve(x*cos(x) = 0, x);
  fsolve(x*cos(x) = 0, x = 6);
  fsolve(x*cos(x) = 0, x = 1..5);

0.  4.712  1.571

Die unterschiedliche Bedeutung von Bezeichnern

In der folgenden Gleichung gl ist "x" der Bezeichner einer Unbekannten:

> gl:= x - 5 = 0:
  gl;

x-5 = 0

gl wird gelöst,
danach wird der Lösungswert von  gl  der Variablen  x als Wert zugewiesen:

> x:= solve(gl, x);

x := 5

Jetzt hat die Variable x den Wert 5.
Der nochmalige Aufruf der letzten Rechenanweisung ergibt eine Fehlermeldung:    

> x:= solve(gl, x);

Error, (in solve) a constant is invalid as a variable, 5

solve(gl,x); wurde soeben interpretiert als solve(gl,5); und dies ist eine offenbar unsinnige Anweisung.

Wenn vor der Wiederholung der Rechenanweisung solve(gl,x); der Wert der Variablen x gelöscht wird, steht danach der Name "x" für die Bezeichnung einer Unbekannten wieder zur Verfügung:

> x:= 'x':
  x:= solve(gl, x);

x := 5


 Home   Back   Top