dh-Materialien
Einführung in Maple    
Übungen
 

Integrale und komplexe Zahlen

> restart; with(plots):

> f:= x -> 1/(1 - x + x^4);

> Graph:= plot(f(x), x = -4..4,
    thickness = 2,
    color = red,
    axesfont = [COURIER, 12],
    labelfont = [COURIER, 13]):
  Fläche:= seq(plot([[i/30, 0], [i/30, f(i/30)]],
    color = gray,
    thickness = 3),
    i = 1..30):
  TextA:=  textplot ([1/2, 0.9, `A`],
    font = [TIMES, BOLD, 25]):
  display([Graph, Fläche, TextA]);

> F(x):= Int(f(x),x);

F(x) := Int(1/(1-x+x^4),x)

Lösung dieses unbestimmten Integrals:

> F(x):= simplify(value(F(x)));

F(x)

Die "Probe":

> simplify(diff(F(x),x));

1/(1-x+x^4)

Lösung der Gleichung  229z4 + 18z2 − 8z + 1 = 0  im Komplexen:

> lgn:= fsolve(229*Z^4 + 18*Z^2 - 8*Z + 1, Z, complex):
  for i to 4 do l[i]:= lgn[i] od;

l[1] := -.1544058929-.3459844740*I
l[2] := -.1544058929+.3459844740*I
l[3] := .1544058929-.8111549413e-1*I
l[4] := .1544058929+.8111549413e-1*I

Hinschreiben des Funktionsterms  F(x) mit Hilfe der Lösungswerte  l1, l2, l3 und l4:

> for i to 4 do
   lnTerm||i:= ln(64*x+2061*l[i]^3+687*l[i]^2+391*l[i]-27):
   sumTerm||i:= l[i]*(-6*ln(2) + lnTerm||i):
  od:
  FSum:= sumTerm||1 + sumTerm||2 + sumTerm||3 + sumTerm||4:
  FSum:= simplify (%);
  unapply(FSum, x):

FSum

Berechnung des Flächeninhalts der grauen Fläche A:

> F1:= evalc(eval(FSum, x = 1));
  F0:= evalc(eval(FSum, x = 0));
  A:= Re(F1 - F0);

F1 := .2e-9*ln(2)-.3593652375+0.*I
F0 := .2e-9*ln(2)-1.847670652+0.*I

A := 1.488305414

Den Wert für A erhält man zwar einfacher, aber vordergründiger (durch numerische Integration) auch so:

> evalf(Int(f(x), x = 0..1));

1.488305414

Die Berechnung von  F(x) für  x infinityfunktioniert nicht ohne Weiteres:

> F[infinity]:= eval(FSum, x = infinity);
  evalc(F[infinity]);


0.+Float(undefined)*I

Aber:

> F[xriesig]:= eval(FSum, x = 10^1000):
  F[rechts]:= evalc(F[xriesig]);
  F[-xriesig]:= eval(FSum, x = -10^1000):
  F[links]:= evalc(F[-xriesig]);
  A[g]:= Re(F[rechts] - F[links]);

F[rechts] := 0.+0.*I
F[links] := -2.683548244+0.*I
A[g] := 2.683548244

Oder (per numerischer Integration) so:

> A[gesamt]:= Int(f(x), x = -infinity..infinity);
  A[gesamt]:= evalf(A[gesamt]);


 Home   Back   Top