dh-Materialien
Maple   
Anwendungen

Lichtbeugung am Mehrfachspalt

> restart; with(plots):

N =   Anzahl der Spalte im Mehrfachspalt:
b =   Spaltbreite in m:
g =   Abstand benachbarter Spalte in m :
λ =   Wellenlänge des benutzten Lichtes in m:

Gangunterschied benachbarter Wellenzüge bei einem optischen Gitter:

> Delta[Gitter]:= g*sin(phi);

Delta[Gitter] := g*sin(phi)

Die zugehörige Phasendifferenz:

> delta[Gitter]:= 2*Pi*Delta[Gitter]/lambda;

Normierte Intensitätsverteilung hinter dem Gitter:

> J[Gitter]:= (sin(N*delta[Gitter]/2)/(sin(delta[Gitter]/2)))^2;

Normierte Intensitätsverteilung hinter einem Spalt:

> J[Spalt]:= sin(Pi*b*sin(phi)/lambda)^2/(Pi*b/N*sin(phi)/lambda)^2;

Normierte Intensitätsverteilung hinter einem Mehrfachspalt:

> J[Mehrfachspalt]:= J[Spalt]*J[Gitter];

Intensitätsverteilung von Beugungsbildern auf einem 3m entfernt stehenden ebenen Schirm:

> J[MSp]:= subs(phi = arctan (x/3), J[Mehrfachspalt]):
J:= simplify(expand(J[MSp]), trig);
J:= unapply(%, [N, b, g, lambda]);

Zeichnen eines Beugungsbildes:

> xMax:= .5;
# Parameterliste: N, b, g, lambda
opts:= 'x = -xMax..xMax,
  color = blue,
  thickness = 1,
  numpoints = 2000,
  axes = none':
plot (J(5, 0.05E-3, 0.3E-3, 500E-9), opts);

MaplePlot


Beugungsversuche mit rotem Laserlicht (λ = 632,8nm, b = 0,05mm, g = 0,1mm):

> xMax:= 0.115:
b:= 0.05E-3;
g:= 0.1E-3;
lambda:= 632.8E-9;

b, g, lambda

Einbinden zweier Beugungsbilder (..\Maple 2023\data\images\*.jpg):  

> ddir:= kernelopts(datadir):
img1 := FileTools:-JoinPath([ddir, "images","laser2.jpg"]):
img2 := FileTools:-JoinPath([ddir, "images","laser4.jpg"]):

Die Beugungsbilder im Vergleich mit den berechneten Intensitätsverteilungen:

> N:= 2;
plot(J(N, b, g, lambda), opts, background = img1);

MaplePlot

> N:= 4;
plot(J(N, b, g, lambda), opts, background = img2);

MaplePlot