dh-Materialien
Maple   
Anwendungen

Das Elektron im Wasserstoffatom

> restart; with(plots):
interface(showassumed = 0):
fnt:= 'font = [COURIER, 12]':

Die Lösungen der Schrödinger-Gleichung des Elektrons im Wasserstoffatom sind separierbar in einen Winkelanteil Y(θ, Φ) und einen Radialanteil R(r).
In diesem Worksheet geht es um die Darstellung von |Y|2 bzw. R2, nicht um die Herleitung der hier lediglich benutzten Gleichungen.

Hinweis: Die Bezeichnungen von Kugelkoordinaten sind leider nicht einheitlich. In Maple wird - wie es im anglo-amerikanischen Sprachraum üblich ist - der Azimutwinkel mit θ und der Polarwinkel mit Φ bezeichnet (siehe Abbildung). Dagegen ist es in der theoretischen Physik genau anders herum: Mit phi bezeichnet man hier meistens den Azimutwinkel und mit theta den Polarwinkel.

Kugelkoordinaten

> psi(r, theta, phi) = Y(theta, phi)*R(r);

Psi(r, theta, phi) = R(r)*Y(theta,phi)

Berechnung der gewöhnlichen Legendre-Polynome legl(x):

> leg:= proc(l)
  1/(2^l*l!)*(D@@l)(x->(x^2-1)^l)(x);
end;

Prozedur leg(l)

Die gewöhnlichen Legendre-Polynome vom Grad 0 bis 3:

> for i from 0 to 3 do leg(i); end do;

1
x
3*x^2/2 - 1/2
x^3 + 3*(x^2-1)*x/2

Berechnung der assoziierten Legendre-Polynome legendre(l, m)(x):

> legendre:= proc(l,m)
  local mabs, pol, dP;
  mabs:= abs(m);

  if (m = 0) then
    dP:= leg(l)
  else
    dP:= diff(leg(l),x$mabs);
  end if;

  pol(x):= (1 - x^2)^(mabs/2)*dP;
  unapply(pol(x), x);
end:

for m from 0 to 2 do
  'legendre'(2,m)(x) = legendre(2,m)(x);
end do;

assoziierte Legendre-Polynome

Kugelflächenfunktionen Y(l, m) für die Quantenzahlen l und m:

> C:= (l,m) -> (-1)^((m+abs(m))/2)*sqrt(((2*l+1)/(4*Pi))*(l-abs(m))!/(l+abs(m))!);
Y:= (l,m) -> C(l,m)*exp(I*m*theta)*legendre(l,m)(cos(phi));

C

Y(l,m)

Wahrscheinlichkeit Ysquared, das Elektron im H-Atom anzutreffen, in Abhängigkeit von θ und Φ:

> Ysquared:= (l,m) -> Y(l,m)*conjugate(Y(l,m)):

orbitalw:= proc(l,m, s)
  local opts;
  opts:= 'coords = spherical,
    scaling = CONSTRAINED,
    grid = [80, 80],
    orientation = [20, 80],
    ambientlight = [1, 1, 0.5]';
  plot3d(Ysquared(l,m),
    theta = 0..2*Pi, phi=0..Pi, opts,
    view = [-s..s, -s..s, -s..s]);
end:

Beispiel für das Elektron mit der Drehimpulsquantenzahl l und der Richtungsquantenzahl m:

> l:= 3:
m:= 1:
assume(sin(phi), nonnegative);
'Y'[l,m] = simplify(Y(l,m), trig);
'Ysqu'[l,m] = simplify(Ysquared(l,m), trig);
orbitalw(l,m, 0.18);

Y[3,1]
Ysqu[3,1]

Orbital

Definition der assoziierten Laguerre-Polynome L(p, q, x):

> `L(p,q,x)`:= (exp(x)*x^(-q)/p!)*Diff(exp(-x)*x^(p+q), x$p);

L:= proc(p,q)
  local f;
  f:= x -> exp(-x)*x^(p+q);
  x -> simplify((exp(x)*x^(-q)/p!)*(D@@p)(f)(x));
end:

L(p,q,x)

Beispiele L(0, q, x), L(1, q, x), L(2, q, x):

> with(orthopoly):
for i from 0 to 2 do normal (L(i,q,x)); end do;

1
q + 1 - x
L(2, q, x)

Die nicht normierten Radialwellenfunktionen des Wasserstoffatoms:

> R:= (n,l) -> rho^l*exp(-rho/2)*L(n-l-1, 2*l+1, rho);

R(n,l)

Normierter Radius rho:

> `rho`:= 2*r/(n*a[0]);

rho:= 2r/n*a[0] 

Der Bohrradius a0:

> a[0]:= 'epsilon[0]*h^2/(Pi*m[e]*e^2)';
`a[0]` = evalf(ScientificConstants[Constant](Bohr_radius)); # in m

a[0]

0.5291772145*10^(-10)

u(r)2 ist ein Maß für die Wahrscheinlichkeit, das Elektron in einer Kugelschale der Dicke dr mit dem Radius r anzutreffen:

> R:= (n,l) -> rho^l*exp(-rho/2)*L(n-l-1, 2*l+1, rho):

n:= 5:
l:= 3:

rho:= 'rho':
`R`[n,l] = R(n,l);
rho:= 2*r/(n*.5291772081e-10):
interface(displayprecision = 3):
'u'[n,l](r)^2 = (R(n,l)*rho)^2;

rmax:= 5E-9:
plot(R(n,l)*rho, r = 0..rmax, fnt,
  color = blue,
  tickmarks = [4, 0]);
plot((R(n,l)*rho)^2,
  r = 0..rmax, fnt,
  color = red,
  tickmarks = [4, 0]);

R[5,3]

u[5,3](r)^2

u(r)

u(r)^2

Normierung von u(r)2.
Die Wahrscheinlichkeit, das Elektron irgendwo in der Atomhülle anzutreffen, ist gleich 1:

> n:= 5:
:= 3:
a[0]:= .5291772081e-10:
rho:= 2*r/(n*a[0]):
u:= unapply(R(n,l)*r, r):
usqunormed:= 4*(n-l-1)!/(n+l)!/(a[0]^3*n^4)*u(r)^2;
probability:= int(usqunormed, r = 0..infinity);

usqunormed

probability:= 1.00

Die normierten Radialwellenfunktionen R(n, l, rho) für die Quantenzahlen n und l:

> n:= 'n': l:= 'l':
a[0]:= 'a[0]':
N:= (n,l) -> 2*sqrt((n-l-1)!/(n+l)!)*a[0]^(-3/2)*n^(-2); ;
R:= (n,l,rho) -> N(n,l)*rho^l*exp(-rho/2)*L(n-l-1,2*l+1,rho);

N(n,l)

R(n,l,rho) 

Die Ψ-Funktion in Abhängigkeit von r, θ und Φ:

> n:= 'n': l:= 'l': m:= 'm': a[0]:= 'a[0]': rho:= 'rho':
rho:= 2*r/(n*a[0]):
unprotect(Psi):
Psi:= (r,theta,phi) -> Y(l,m)*R(n,l,rho);

Psi(r, theta, phi)

Visualisierung der Gleichung Ψ2(r, θ, Φ) = p:

> n:= 5:
l:= 3:
m:= 1:

'psi'[n,l,m](r,theta,phi) = simplify(Psi(r,theta,phi));

a[0]:= 1;

opts:= 'coords=spherical,
  scaling = CONSTRAINED,
  grid = [25, 25, 25],
  axes = framed, fnt,
  orientation = [40, 75],
  style = patchnogrid,
  lightmodel = light4':

p:= 0.0003/n^3;
evalf(subs(theta = 0, Psi(r,theta,phi)^2)) = p:
implicitplot3d(%, r=0..45, theta=0..2*Pi, phi=0..Pi, opts);

Psi[5,3,1](r, theta, phi) 

a[0]:= 1; p:= 0.240*10^(-5)

implicitplot3d

Darstellung der Aufenthaltswahrscheinlichkeit prob des Elektrons im Schnitt längs der z-Achse:

> n:= 5:
:= 3:
m:= 1:

a[0]:= 1;

prob:= evalf(subs(theta = 0, Psi(r,theta,phi)^2)):
'psi'[n,l,m](r,0,phi)^2 = simplify (prob);

opts:= 'style=contour,
  grid = [50, 50],
  contours = 40,
  color = navy,
  orientation = [0, 0]':

plot3d ([r*cos(phi), r*sin(phi), prob],
   r = 0..52,
   phi = 0.01..2*Pi,
   opts);

a[0]:= 1

Psi[5,3,1](r, 0, phi)^2 

Aufenthaltswahrscheinlichkeit des Elektrons im Schnitt längs der z-Achse

Die gleiche 3D-Graphik, etwas gedreht (orientation = [-14,45]):

Aufenthaltswahrscheinlichkeit des Elektrons im Schnitt längs der z-Achse


 Home   Back   Top