Maple-Worksheet: Kugeln

Kugeln, Ebenen und Geraden

> restart; with(geom3d):

interface(showassumed = 0):
fnt:= 'font = [COURIER, 12]':

Definition der Kugel K mit dem Mittelpunkt M und dem Radius r:

> point(M, 2, 2, 2):

r:= 3:
sphere(K, [M, r]):
Equation(K, [x, y, z]);

Definition der Ebene E mit der Gleichung x − 2∙y + 1,2∙z = 2 :

> plane(E, x - 2*y + 1.2*z = 2, [x, y, z]):

> draw([K, E (color = green,

  style = patchnogrid)],
  axes = boxed, fnt,
  orientation = [23, 59],
  view = [-2..6, -2..6, -2..6]);

Definition einer Ebene F:

> plane(F, a*x + b*y + z = d, [x, y, z]):

Equation(F);

Unter welcher Bedingung (cond1) stehen E und F senkrecht aufeinander?

> ArePerpendicular(E, F, cond1):
cond1;

Neudefinition von F mit a = 1 und b = 1,1:

> plane(F, x + 1.1*y + z = d, [x, y, z]):

Equation(F);

F ist Tangentialebene der Kugel K, wenn distance (M, F) = r:

> distance(M, F);

solve(% = r);
d:= max(%[1], %[2]);

> Equation(E);

Equation(F);
draw([K,
      E (color = green, style = patchnogrid),
      F (color = red, style = patchnogrid)],
      axes = boxed, fnt,
      orientation = [149, 53],
      view = [-2..6, -2..6, -2..6]);

Bestimmung des Berührpunktes B mit Hilfe der Geraden g.
g geht durch den Kugelmittelpunkt M und steht senkrecht auf der Ebene F:

> line(g, [M, [1, 1.1, 1]]):

intersection(B, g, F):
B:= evalf(coordinates(B), 3);