dh-Materialien
Maple   
Anwendungen

Erzwungene Schwingungen

> restart;
fnt:= 'font = [COURIER, 12]':

Erzwungene Schwingung eines Federpendels mit Reibung;
die Reibungskraft sei proportional zur Geschwindigkeit des Pendelkörpers;
m = Masse des Pendelkörpers, K = Federkonstante:     

> s:= t -> x(t):
v:= t -> diff (x(t),t):
a:= t -> diff (x(t),t,t):

DGL:= m*a(t) + R*v(t) + K*x(t) = F[0]*cos(omega*t):
DGL;

Lösung der Differentialgleichung DGL für v(0) = 0 und x(0) = 0

> x(t):= rhs(dsolve({DGL, D(x)(0)= 0, x(0)= 0}, x(t)));


 


 

Zahlenbeispiel mit Schaubild:

> m:= 6:  F[0]:= 0.3:  K:= 1.4:  R:= 0.32:  omega:= 0.2:
plot([x(t), sin(omega*t)], fnt,
  t = 0..60*Pi,
  color = [red, blue]);

[Maple Plot]

Nach dem Einschwingvorgang schwingt das Federpendel sinusförmig (rot),
aber phasenverschoben zur erzeugenden Schwingung (blau).
Also ist es vernünftig, x(t) = x0 sin(ωt + Φ)  zu schreiben:

> restart;
fnt:= 'font = [COURIER, 12]':
s:= t -> x0*sin(omega*t + phi):
v:= t -> D(s)(t):
a:= t -> D(v)(t):

DGL:= m*a(t) + R*v(t) + K*s(t) = F[0]*cos(omega*t):
DGL;

Diese Gleichung liefert mit zwei verschiedenen Werten von t  gl1 und gl2:

> gl1:= subs(t = 0, DGL): gl1;
gl2:= subs(omega*t = Pi/4, DGL): gl2;

Eliminieren von Φ und die hierdurch gelieferte Gleichung  gl:

> eliminate({gl1, gl2}, phi):
gl:= op (1, op (2, %[1]))^2 = 0;

gl

Auflösen der Gleichung  gl  nach x0 :

> lgn:= solve(gl, x0): lgn;
x0(R, omega):= lgn[1];
x0:= unapply(x0(R, omega), (R, omega)):


Die Amplitude x0 der erzwungenen Schwingung in Abhängigkeit von ω für verschiedene Dämpfungen:

> m:= 3:  F[0]:= 0.3:  K:= .9:  
plot([x0(6.0,omega),
      x0(2.3,omega),
      x0(1.3,omega),
      x0(0.8,omega),
      x0(0.4,omega),
      x0(0.2,omega)],
      omega = 0..1.6,
      color = [red, blue, maroon, navy, orange]);

[Maple Plot]

Berechnung der Resonanzstelle:

> m:= 'm':  F[0]:= 'F[0]':  K:= 'K':
solve(diff(x0(R, omega), omega) = 0, omega);

> simplify(subs(R = 0, %[2]));

(K*m)^(1/2)/m

Dies entspricht der Eigenfrequenz des Federpendels:

> restart;
s:= t -> x(t):
v:= t -> D(s)(t):
a:= t -> D(v)(t):

DGL:= m*a(t) + K*s(t) = 0: DGL;
dsolve({DGL, D(s)(0) = 0, s(0) = x0}, s(t));